continua (next page) Ray Tracing index main index
// scrivania.pov
// (alfmar 1996-07-18)

#include "colors.inc"
#include "textures.inc"
#include "shapes.inc"
#include "shapes2.inc"

#declare Bottiglia = union
{
  cone       { <0,0,0>, 28, <0,2,0>,   30                              }
  cylinder   { <0,0,0>,     <0,142,0>, 30  open    translate <0,2,0>   }
  cone       { <0,0,0>, 30, <0,4,0>,   11  open    translate <0,144,0> }
  cylinder   { <0,0,0>,     <0,7,0>,   11  open    translate <0,148,0> }
  cylinder   { <0,0,0>,     <0,2,0>,   13          translate <0,152,0> }
  object     { Hexagon      scale <11,9,9>
                            rotate <40,0,90>       translate <0,155,0> }
  cone       { <0,0,0>, 8,  <0,14,0>,  3.6         translate <0,165,0> }

  bounded_by { cylinder { <0,0,0>, <0,182,0>, 30 } }
}


#declare Scrivania = union
{
// corpo:
  box { <0,0,0>, <1050, 19, 510>  translate <-525, 756, -255> }  // base
  box { <0,0,0>, <19,  756, 458>  translate <-497,   0, -230> }  // piede sx
  box { <0,0,0>, <19,  756, 458>  translate <478,    0, -230> }  // piede dx
  box { <0,0,0>, <956,  19, 437>  translate <-478, 638, -225> }  // sottobase
  box { <0,0,0>, <19,   99, 435>  translate <-26,  657, -223> }  // divisore
  box { <0,0,0>, <956, 214,  19>  translate <-478, 542,  208> }  // chiusura

// cassetto:
  box { <0,0,0>, <485, 118,  19>  translate <-7,   638, -221> }  // frontale

  union                                          // listello di abbellimento
  {
    difference
    { box { <0,0,0>, <381,  58, 3> }
      box { <7,7,0>, <374,  51, 3> } translate <45, 678, -224>  }

    intersection
    { box { <0,0,0>, <377,  54, 2> }
      box { <3,3,0>, <374,  51, 2> } translate <47, 680, -226>  }
  }

  cone     { <235.5, 707, -221>, 8.5,
             <235.5, 707, -236>, 17
             open }    // interessa solo il contorno

  cylinder { <235.5, 707, -236>,
             <235.5, 707, -241>, 17
             open }    // interessa solo il contorno

  cone     { <235.5, 707, -241>, 17,
             <235.5, 707, -244>, 15  }

  bounded_by { box { <-525, 0, -255>, <525, 775, 255> } }
}


#declare Trifoglio = quartic
{
  < 1,  0, 0, -23,  0,  0,  0,  0,   0,  0,  0,  0,  0,  0,  73,
    0,  0,  0,  0,  0,  1,  0, -23,  0,  0,  0,  0,  0,  0,  0,
    1, -23, 0,  0, 50>

  rotate <0, 45, 45>

  bounded_by { box { <-30,-10,-50>, <60,40,50> } }
}


#declare Cuboide = quartic
{
  < 1.0,  0.0,  0.0,   0.0,    0.0,  0.0,  0.0,  0.0,  0.0,   0.0,
    0.0,  0.0,  0.0,   0.0,    0.0,  0.0,  0.0,  0.0,  0.0,   0.0,
    1.0,  0.0,  0.0,   0.0,    0.0,  0.0,  0.0,  0.0,  0.0,   0.0,
    1.0,  0.0,  0.0,   0.0, -1000.0 >
}


//  descrizione della scena...

plane  { y, 0
         pigment
         {
           hexagon color Silver color Gold color Bronze
           turbulence 0.06
         }
         finish  { Metal  crand 0.08  roughness 0.43  }
         scale 73
       }

plane  { z, 750
         texture
         {
           PinkAlabaster
           normal { bumps 0.5333 scale 445 }
           scale 260
         }
       }

object { Scrivania
         texture
         {
           Pine_Wood scale 31 rotate <19, 71, 37>
         }
         normal { ripples 0.33  frequency 0.071  scale 11 }
       }

object { object  { Bottiglia  scale 1.4   rotate <0,0,-19> }
         texture
         {
           pigment { Copper }
           finish  { Phong_Dull  crand 0.08  roughness 0.35 }
           scale 12
         }
         translate <-100, 870, 100>
       }

object { object  { Bottiglia  scale 1.3  rotate <0,0,7> }
         pigment { DarkOliveGreen }
         finis`  { Phong_Dull  crand 0.12 }
         translate <-235, 800, -70>
       }

object { object  { Bottiglia  scale 1.1 }
         pigment { ForestGreen }
         finish  { Phong_Dull  crand 0.23 }
         translate <290, 945, -160>
       }

object { object  { Cuboide  scale 7  rotate <29, 41, 7> }
         pigment { hexagon
                     color red 0.3 green 0.3 blue 0.98
                     color red 0.3 green 0.4 blue 0.95
                     color red 0.4 green 0.3 blue 0.95
                   scale 7
                 }
         finish  { Phong_Glossy }
         translate <260, 880, 200>
       }

object { object  { Cuboide  scale 11  rotate <2, 41, 23> }
         pigment { hexagon
                     color red 0.4 green 0.4 blue 0.88
                     color red 0.5 green 0.4 blue 0.85
                     color red 0.4 green 0.5 blue 0.90
                   scale 6
                 }
         finish  { Phong_Glossy }
         translate <130, 1100, 215>
       }

object { object  { Cuboide  scale 16  rotate <23, 41, 43> }
         pigment { hexagon
                     color red 0.45 green 0.45 blue 0.85
                     color red 0.55 green 0.45 blue 0.83
                     color red 0.45 green 0.55 blue 0.81
                   scale 5
                 }
         finish  { Phong_Glossy }
         translate <-230, 1070, 190>
       }

object { object  { Trifoglio scale 1.2  rotate <-19, 0, 23> }
         texture { Gold_Texture }
         translate <-350, 800, -170>
       }

object { object { Trifoglio scale 0.9 }
         texture { Chrome_Texture }
         translate <-150, 830, -140>
       }

object { object { Trifoglio scale 1.7  rotate <-41, 0, 0> }
         texture { PinkAlabaster }
         translate <50, 915, 120>
       }

object { object { Trifoglio scale 1.3  rotate <-11, 23, 0> }
         texture { Chrome_Texture }
         translate <10, 875, -200>
       }

object { object  { Trifoglio scale 2.2  rotate <-23, 79, 0> }
         texture
         {
           Brass_Texture
           normal  { ripples 0.3  frequency 0.09  scale 100}
         }
         translate <300, 840, -200>
       }


light_source  { <-500, 3000,  1500>  color LimeGreen  }
light_source  { <1500, 3000, -1500>  color Aquamarine }
light_source  { <-240,  680,   150>  color Magenta    }

fog { color Gray65
      distance 6500 }

camera { location <50, 1100, -900> look_at <50, 750, 0> }


The rendered image. Click here for next page.

indietro (previous page) - Ray Tracing index - send e-mail - continua (next page)